Līklīniju trapeces laukums

1. programma

Aplūkosim trapeču metodi līklīniju trapeces laukuma aprēķināšanai.

Par līklīniju teapeci sauksim figūru, kuru ierobežo x ass, taisnes y=a, y=b un funkcijas y=f(x) grafiks.

Citiem vārdiem sakot, ja taisnleņķa trapeces garāko sānu malu aizstāj ar līkni, iegūst līklīniju trapeci. Arī pati taisnleņķa trapece un taisnstūris ir līklīniju trapeces (tad f(x) grafiks ir taisne).

Tātad, kā aprēķināt šādas figūras laukumu, ja doti ir a, b un f(x) formula?

Sadalīsim nogriezni [a,b] n vienādās daļās un dalījuma punktus apzīmēsim ar x0, x1, x2, ... , xn-1, xn kā redzams attēlā. Caur dalījuma punktiem novilksim y asij paralēlus nogriežņus, tādējadi sadalot līklīniju trapeci n mazākas līklīniju trapecītēs. Katrai trapecītei līko malu aizstāsim ar nogriezni, iegūstot parastas trapeces, kuru laukumu mākam aprēķināt. Protams, aizstājot līko malu ar nogriezni, mēs laukumu varam samazināt vai palielināt. Taču, ja n ir pietiekami liels, atšķirība nebūs liela. Jeb palielinot n mēs palielināsim aprēķinu precizitāti.

Tātad atliek izvēlēties pietiekami lielu n (piemēram, 100000), un atrast visu n trapeču laukumu summu.

Aplūkosim vēl kā aprēķināt pirmās trapeces laukumu (citām to veic līdzīgi). Trapeces augstums ir h=(b-a)/n. Viens pamata garums ir f(x0), otrs - f(x1), kur x0=a un x1=x0+h. Tātad S1=(f(x0)+f(x1))/2*h un viss laukums ir 

var a,b,h,x,S:real;
    n,i:longint;
function f(x:real):real;
begin
  f:=x*x;
end;
begin
  a:=0;
  b:=2;
  n:=100000;
  h:=(b-a)/n;
  S:=f(a)/2;
  x:=a;
  for i:=1 to n-1 do begin
    x:=x+h;
    S:=S+f(x);
  end;
  S:=S+f(b)/2;
  S:=S*h;
  writeln('S=',S:1:4);
  readln;
end.

3.-6. Trapeces līko malu definēsim kā lietotāja definētu funkciju.
8.-9. Līklīniju trapeces pamatu atrašanās vietas
10. Dalījumu skaits jeb precizitāte.
12. Iekavu summas pirmais saskaitāmais.
14.-17. Pieskaitām visas vidējās trapeces.
18. Vēl pēdējais saskaitāmais.
19. Atliek iegūto summu sareizināt ar augstumu.

Uzdevumi

  1. Aprēķināt attēlā redzamā trijstūra laukumu, izmantojot un neizmantojot trapeču formulu. Ko var secināt, izmēģinot dažādas n vērtības.
  2. Aprēķināt attēlā redzamo laukumu. [2]
  3. Aprēķināt laukumu, ko ierobežo grafiki y=x2, x=1, x=5 un y=0. [41,3333]
  4. Aprēķināt laukumu, ko ierobežo grafiki y=x2 un y=x+2. [4,5]
  5. Aprēķināt laukumu, ko ierobežo grafiki y=x2-4 un y=x+2. Padomā, kā lietot trapeču formulu, ja laukums pilnībā vai daļēji atrodas zem x ass. [20,8333]